【Access】データベースを使って項目に順番をつける

Function RAgariRenban()

    Dim db As DAO.Database
    Dim rst As DAO.Recordset
    Dim strSQL As String
    Dim BL_DATE As Date, BL_ZYOMEI As String, BL_R As Integer
    Dim BL_AGARI As Double, BL_SEQ As Integer
    Dim i As Long, n As Long

    strSQL = "SELECT 開催日, 場名, Ｒ, 推定上り, 推定上り順" & " "
    strSQL = strSQL & "FROM WK_DT" & " "
    strSQL = strSQL & "WHERE 推定上り > 0" & " "
    strSQL = strSQL & "ORDER BY 開催日, 場名, Ｒ, 推定上り"
    strSQL = strSQL & ";"

    'カレントデータベースを変数に代入する
    Set db = CurrentDb
    
    'クエリを実行してレコードセットを開く
    Set rst = db.OpenRecordset(strSQL, dbOpenDynaset)
        
    RAgariRenban = False
    If rst.RecordCount <= 0 Then Exit Function

    i = 1

        Do
            rst.Edit
            If i = 1 Then
                BL_DATE = rst!開催日
                BL_ZYOMEI = rst!場名
                BL_R = rst!R
                BL_AGARI = rst!推定上り
                BL_SEQ = 1
                n = 0
            End If
'''ブレイクkey
            If BL_DATE = rst!開催日 And BL_ZYOMEI = rst!場名 And BL_R = rst!R Then
                If BL_AGARI = rst!推定上り Then
'''ここまで一緒だと「推定上り順」は重複する
                    rst!推定上り順 = BL_SEQ
                    If i > 1 Then
                        n = n + 1
                    End If
                Else
                    BL_SEQ = BL_SEQ + 1 + n
                    rst!推定上り順 = BL_SEQ
                    BL_AGARI = rst!推定上り
                    n = 0
                End If
            Else
                BL_DATE = rst!開催日
                BL_ZYOMEI = rst!場名
                BL_R = rst!R
                BL_AGARI = rst!推定上り
                BL_SEQ = 1
                n = 0
                rst!推定上り順 = BL_SEQ
            End If
    
            rst.Update
            
            i = i + 1
            rst.MoveNext
        Loop Until rst.EOF = True
    
    rst.Close
    RAgariRenban = True
End Function